利用自带的 Automator 创建自动脚本，并通过快捷键在当前目录生成文本文件以便编辑。

V2EX = way to explore

V2EX 是一个关于分享和探索的地方

现在注册

已注册用户请登录

这是一个创建于 1726 天前的主题，其中的信息可能已经有所发展或是发生改变。

分享我的一个日常操作，我习惯性在当前目录下创建文件，然后打开编辑，但是 MacOS 没有创建文件的选项。但是我们可以通过自带的 Automator 创建工作流，然后绑定快捷键来实现这个目的。以下是我的操作步骤。同时我在 B 站录制了视频，食用更香，欢迎各位前往观看，记得三连哦！

视屏地址： https://www.bilibili.com/video/BV1Vg4y1872j

操作步骤：

打开Automator并选择Quick Action。
Workflow receives current选择no input 然后把any application改为Finder.app。
在左侧Actions搜索Run AppleScript并将其拖到右侧空白区域。
粘贴我们事先准备的代码（该代码由Rarylson Freitas提供）

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell